source: nikanabo/current/bsl/onilight/IGMD/manplant/manplant.bsl@ 833

#################
### VARIABLES ###
#################

var int var_counter = 0;

############
### MAIN ###
############

func void main(void)
{
gl_fog_red = .15
gl_fog_blue = .15
gl_fog_green = .15
gl_fog_start = .995
gs_farclipplane_set 5000
ui_suppress_prompt = 1
chr_auto_aim_dist = 0
start
}

#############
### START ###
#############

func void start(void)
{
fork deactivate_stuff
if(save_point eq 0) save_point = 1
if(save_point eq 1) fork intro
if(save_point eq 2) restore_game
if(save_point eq 3) restore_game
if(save_point eq 4) restore_game
sleep 5
fork sp_all
}

func void deactivate_stuff(void)
{
trigvolume_setscript save_point4 sp4 entry
#not used
trigvolume_enable alarm_1 0
trigvolume_enable brain_commguy_1 0
trigvolume_enable febtober2 0
trigvolume_enable flyway_1 0
trigvolume_enable Griffin 0
trigvolume_enable hidden_1a 0
trigvolume_enable hidden_1b 0
trigvolume_enable lowthug_1 0
trigvolume_enable new_target_3 0
trigvolume_enable nook_1 0
trigvolume_enable nookright 0
trigvolume_enable outro1 0
trigvolume_enable plasma_striker_1 0
trigvolume_enable sound_off 0
trigvolume_enable trigger_active_1 0
trig_deactivate 201
trig_deactivate 202
trig_deactivate 203
trig_deactivate 204
trig_deactivate 2012
trig_deactivate 2022
particle lock_1_locklight01 do start
particle lock_1b_locklight01 do start
env_show 555 0
door_lock 1
#used
trigvolume_enable febtober 0
trigvolume_enable tech_1 0
trig_hide 205
trig_hide 2013
trig_hide 2023
trig_hide 2032
trig_hide 2042
obj_create 1201 1208
env_anim 1201 1208
door_unlock 3
door_lock 4
door_lock 9
door_lock 21
console_deactivate 6
}

func void you_lose(void)
{
fade_out 0 0 0 30 
sleep 30
lose
}

####################################
### SEVERAL TIMES USED FUNCTIONS ###
####################################

func void sp_all(void)
{
co_message_display = 0
if(save_point eq 1) save_game 1 autosave
if(save_point eq 2) save_game 2 autosave
if(save_point eq 3) save_game 3 autosave
if(save_point eq 4) save_game 4 autosave
sleep 180
co_message_display = 1
}

func void remove_ai(void)
{
ai2_kill
sleep 60
powerup_reset
weapon_reset
sleep 240
corpse_reset
}

func void music_stop(void)
{
sound_music_stop mus_fiteb_hd
sound_music_stop atm_low_perc1
sound_music_stop atm_cl12
}

##########
### SP1 ###
##########

func void intro(void)
{
chr_inv_reset 0
ai2_spawn nookleft_thug_1
ai2_spawn nookright_thug_1
ai2_spawn ambush_striker_1
ai2_spawn ambush_striker_2
ai2_spawn ambush_striker_3
ai2_spawn partner_cop_1
ai2_spawn partner_cop_2
ai2_attack partner_cop_1 ambush_striker_1
ai2_attack partner_cop_2 ambush_striker_3
ai2_makeaware nookleft_thug_1 konoko
ai2_makeaware nookright_thug_1 konoko
objective_set 1 silent
target_set 38 30
sleep 1
sound_music_start mus_fiteb_hd 0.75
sound_dialog_play c00_01_22shinatama
}

#tv3 - after door 3 (entry func: nookright); I've disabled it
#tv1 - between door 2 and door 4 (entry func: nook_1); I've disabled it

#lose func of ambush_striker_1
func void striker_lullaby_1(void)
{
striker_lullaby_3
}

#lose func of ambush_striker_2
func void striker_lullaby_2(void)
{
striker_lullaby_3
}

#lose func of ambush_striker_3
func void striker_lullaby_3(void)
{
var_counter = var_counter + 1
if(var_counter eq 3)
        {
        particle foyer_right_locklight01 do start
        door_unlock 21
        trigvolume_enable tech_1 1
        var_counter = 0
        music_stop
        }
}

#tv2 - in front of door 21
func void tech_1(void)
{
ai2_spawn tech_thug_1
ai2_spawn tech_thug_1a
ai2_dopath partner_cop_1 cop_backup_1a 1
ai2_dopath partner_cop_2 cop_backup_1b 1
}

#tv28 - after door 21 (func: all_music_counters); I've disabled it
#tv25 - complete room (func: feb_tober2); I've disabled it

#console1
func void door_1(void)
{
door_lock 8
door_lock 15
ai2_spawn plasma_striker_1
particle febtober1_locklight01 do start
particle lock_1a_locklight01 do start
particle save1a_locklight01 do start
door_unlock 19
target_set 123 30
}

#tv5 - after door 19
func void bait_1(void)
{
ai2_spawn bait_commguy_1
ai2_spawn tech_thug_2
sleep 120
ai2_doalarm bait_commguy_1 15
sound_music_start atm_low_perc1 1.00
particle save1b_locklight01 do start
door_unlock 11
ai2_dopath partner_cop_1 cop_backup_2a 1
ai2_dopath partner_cop_2 cop_backup_2b 1
}

#tv13 - after door 13 (enter func: plasma_striker_1, loop func: calling_all_cars); I've disabled it
#tv6 - after door 12 (func: calling_all_cars2); I've disabled it

#console15
func void alarm_1(void)
{
ai2_spawn hall_striker_2
sound_ambient_start alarm_loop
sleep 900
sound_ambient_stop alarm_loop
}

##########
### SP2 ###
##########

#tv18 - after door 11
func void tech_ambush_1(void)
{
if(save_point eq 2)
        {
        door_lock 8
        door_lock 15
        ai2_spawn plasma_striker_1
        particle save1b_locklight01 do start
        door_unlock 11
        objective_set 1 silent
        target_set 38 30
        sleep 1
        sound_music_start atm_low_perc1 1.00
        sound_dialog_play c00_01_22shinatama
        }
else save_game 2 autosave
ai2_spawn hall_striker_1
door_lock 10
door_lock 12
}

#console3
func void door_2(void)
{
particle febtober1_locklight01 do start
particle lock88_locklight02 do start
door_unlock 10
door_unlock 23
ai2_spawn patrol_striker_2
console_activate 4 1
target_set 124 30
sound_dialog_play c00_01_27shinatama
}

#tv7 - in front of door 7
func void cruel_1(void)
{
ai2_spawn cruel_commguy_1
ai2_spawn victim_femsci_1
}

#console4
func void door_3(void)
{
music_stop
particle lock_3_locklight01 do start
door_unlock 4
ai2_spawn tech_thug_3
objective_set 2 silent
target_set 128 30
sound_dialog_play c00_01_26shinatama
}

#tv4 - in some distance in front of door 23 (func: flyway_1); I've disabled it

#tv19 - after door 23
func void new_target_1(void)
{
sound_music_start atm_cl12 0.75
target_set 54 30
}

#tv15 - at the beginning of the stairs after door 24
func void beaters_1(void)
{
chr_delete plasma_striker_1
door_unlock 8
door_unlock 15
ai2_spawn scram_striker_1
ai2_spawn beater_thug_1
particle vent01 start
}

#lose func of beater_thug_1
func void beater_thug_2(void)
{
ai2_spawn beater_thug_2
}

#lose func of scram_striker_1
func void backup_2(void)
{
ai2_spawn backup_thug_2
ai2_tripalarm 2 0
}

#tv16 - in front of door 16 (enter func: scramble_sound_off, loop func: Griffin_1); I've disabled it
#tv10 - after door 16 (enter func: set_objective_3, inside func: lowthug_1, leave func: disable_obj_trig_1); I've disabled it

##########
### SP3 ###
##########

#tv26 - in some distance in front of door 15
func void save_point_3(void)
{
if(save_point ne 3)
        {
        fork remove_ai
        save_game 3 autosave
        particle vent01 do stop
        music_stop
        }
particle hlock_1_locklight01 do start
door_unlock 22
particle vent02 do start
trig_activate 2
door_close 16
door_lock 16
trigvolume_enable febtober 1
ai2_spawn hidden_sci_1
ai2_spawn low_thug_1
ai2_spawn low_thug_2
objective_set 3 silent
target_set 127 30
sleep 1
sound_dialog_play c00_01_18shinatama
}

#tv8 - in front of door 22  (func: hidden_1b); I've disabled it
#tv9 - after door 22  

#console7
func void guardroom_1(void)
{
particle guardroom_1_locklight01 do start
door_unlock 14
ai2_spawn patrol_striker_3
ai2_spawn brain_commguy_1
ai2_spawn brain_commguy_2
console_deactivate 6
target_set 65 30
}

#tv13 - at the beginning of the upper way, next to where the stairs ends (func: trigger_active_1); I've disabled it

#tv24 - after the railing
func void feb_tober(string ai_name)
{
fade_out 0 0 0 30
sleep 30
chr_teleport 0 41
chr_facetoflag 0 126
fade_in 30
trigvolume_reset febtober
}

#tv11 - after door 14 (func: brain_commguy_1); I've disabled it

#console8
func void brainlock_1(void)
{
ai2_spawn low_striker_1
ai2_spawn low_striker_2
console_activate 6
target_set 126 30
}

#tv12 - after door 8
func void low_striker_1(string ai_name)
{
ai2_spawn low_striker_1
ai2_spawn low_striker_2
}

#tv20 - in front of the furniture with console6 (func: new_target_3); I've disabled it

#console6
func void trigger_deactivate_4(void)
{
particle guardroom_2_locklight01 do start
door_unlock 9
trig_deactivate 4
console_activate 5
target_set 125 30
}

#console5
func void hidden_1(void)
{
particle brainlock_1_locklight02 do start
door_unlock 6
target_set 129 30
trigvolume_enable cruel_striker_1 1
}

#tv21 - in front of door 6
func void cruel_striker_1(void)
{
ai2_spawn cruel_striker_1
ai2_spawn victim_mansci_1
brain_start
}

func void brain_start(void)
{
particle brainlock_2_locklight01 do start
particle brain do start
particle brain1 do start
trig_show 205
trig_show 2013
trig_show 2023
trig_show 2032
trig_show 2042
trig_speed 205 .4
trig_speed 2013 .4
trig_speed 2023 .4
trig_speed 2032 .4
trig_speed 2042 .4
}

#called up, after you have talked to the scientist
func void flee(void)
{
chr_talk victim_mansci_1 c02_62_11sci 0 0
ai2_dopath victim_mansci_1 victim_2
sleep 300
objective_set 4 silent
sound_dialog_play c00_01_20shinatama
}

#tv17 - in front of the beginning of the stairs (func: outro); not used

##########
### SP4 ###
##########

#tv27 - after door 26
func void sp4(void)
{
if(save_point eq 4)
        {
        brain_start
        objective_set 4 silent
        sleep 1
        sound_dialog_play c00_01_20shinatama    
        }
else
        {
        save_game 4 autosave
        fork remove_ai
        particle brainlock_1_locklight02 do stop
        door_lock 6
        particle vent02 stop
        }
turret_deactivate 20
particle brainlock_3_locklight01 do start
door_unlock 27
sound_ambient_start deadlybrain_sound 1.0
sound_music_start mus_cool4_hd 1
}

#tv22 - in some distance after door 27
#tv23 - in some distance after door 27 on the right side
func void lockit(void)
{
particle brainlock_3_locklight01 do stop
door_close 27
door_jam 27
}

#console21, console22, console23 and console24
func void brain_counter(void)
{
var_counter = var_counter + 1
if(var_counter eq 4)
        {
        fade_out 0 0 0 30
        sleep 30
        win
        }
}

#####################
### TEXT CONSOLES ###
#####################

func void level2a(string chr_index)
{
text_console level_2a
console_reset 2
}

func void level2b(string chr_index)
{
text_console level_2b
console_reset 12
}

func void level2c(string chr_index)
{
text_console level_2c
console_reset 13
}

func void level2d(string chr_index)
{
text_console level_2d
console_reset 14
}

func void level2e(string chr_index)
{
text_console level_2e
console_reset 11
}