source: nikanabo/current/bsl/onilight/IGMD/tctf/tctf.bsl@ 1193

#################
### VARIABLES ###
#################

var int var_counter = 0;
var int var_counter2 = 0;

############
### MAIN ###
############

func void main(void)
{
gl_fog_red = 0
gl_fog_blue = 0
gl_fog_green = 0
gl_fog_start = .995
gs_farclipplane_set 5000
ui_suppress_prompt = 1
chr_auto_aim_dist = 0
start
}

#############
### START ###
#############

func void start(string ai_name)
{
fork deactivate_stuff
if(save_point eq 0) save_point = 1
if(save_point eq 1) fork intro
if(save_point eq 2) restore_game
if(save_point eq 3) restore_game
if(save_point eq 4) restore_game
sleep 5
fork sp_all
}

func void deactivate_stuff(void)
{
#not used
trigvolume_enable t86 0
trigvolume_enable trigger_volume_99 0
#used
env_show 97 0
env_show 98 0
env_show 321 0
env_show 322 0
env_show 323 0
env_show 324 0
env_show 325 0
env_show 398 0
env_show 601 0
env_show 602 0
trig_deactivate 1
trig_deactivate 2
trig_deactivate 3
trig_deactivate 4
trig_deactivate 5
trig_deactivate 6
trig_deactivate 7
trig_deactivate 8
trig_deactivate 9
trig_deactivate 10
trig_deactivate 60
trig_deactivate 61
trig_deactivate 62
trig_deactivate 63
trig_deactivate 64
trig_deactivate 65
trig_deactivate 70
trig_deactivate 71
trig_deactivate 72
trig_deactivate 73
trig_deactivate 74
trig_deactivate 75
trig_deactivate 98
trig_deactivate 99
trig_deactivate 100
trig_deactivate 101
trig_deactivate 302
trig_deactivate 303
trig_deactivate 310
trig_deactivate 320
trig_deactivate 400
trig_deactivate 500
trig_deactivate 501
trig_deactivate 502
trig_deactivate 503
trig_deactivate 510
trig_deactivate 511
trig_deactivate 512
trig_deactivate 520
trig_deactivate 521
trig_deactivate 522
trigvolume_enable z_40t 0
trigvolume_enable zz_40t 0
trigvolume_enable zzz_40t 0
trigvolume_enable zzzz_40t 0
trigvolume_enable tv_61t 0
trigvolume_enable trigger_volume_81 0
}

func void you_lose(string ai_name)
{
fade_out 0 0 0 30
sleep 30
lose
}

####################################
### SEVERAL TIMES USED FUNCTIONS ###
####################################

func void sp_all(void)
{
co_message_display = 0
if(save_point eq 1) save_game 1 autosave
if(save_point eq 2) save_game 2 autosave
if(save_point eq 3) save_game 3 autosave
if(save_point eq 4) save_game 4 autosave
sleep 180
co_message_display = 1
}

func void remove_ai(void)
{
ai2_kill
sleep 60
powerup_reset
weapon_reset
sleep 240
corpse_reset
}

func void music_stop(void)
{
sound_music_stop mus_asianb
sound_music_stop mus_pursuit
sound_music_stop mus_om01
}

#tv86 to tv97
func void fire_damage(string ai_name)
{
chr_poison(ai_name, 5, 30, 30);
}

##########
### SP1 ###
##########

### GARAGE - GROUND FLOOR ###

func void intro(void)
{
env_show 99 1
env_show 101 1
env_show 103 1
env_show 104 1
env_show 105 1
env_show 106 1
env_show 107 1
env_show 108 1
env_show 110 1
env_show 111 1
env_show 112 1
env_show 321 1
env_show 322 1
env_show 323 1
env_show 324 1
env_show 325 1
env_shade 321 325 .6 .6 .6
env_show 444 1
ai2_spawn lobby_striker_01
ai2_spawn lobby_striker_02
ai2_spawn lobby_striker_03
playback 0 IntroKonoko
particle smoke do start
particle security_locklight01 do start
particle LobbyWall do explode
objective_set 1 silent
target_set 323 30
sleep 1
sound_dialog_play c07_22_01konoko
sound_music_start mus_asianb
}

#tv9 - left ramp between ground floor and 1st floor
func void spawnG3_11(string ai_name)
{
ai2_spawn garage_striker_07
ai2_passive garage_striker_07 1
ai2_spawn garage_striker_08
playback garage_striker_07 garage_taunt
ai2_passive garage_striker_07 0
}

#tv12 - left ramp between ground floor and 1st floor, after tv9
func void killG2_08(string ai_name)
{
trigvolume_enable trigger_volume_G2_08 0 
}

#tv7 - right ramp between ground floor and 1st floor
func void spawnG2_7(string ai_name)
{
ai2_spawn garage_striker_01
ai2_spawn garage_striker_02
}

#tv13 - right ramp between ground floor and 1st floor, after tv7
func void killG2_10(string ai_name)
{
trigvolume_enable trigger_volume_G2_10 0 
}

#tv50 - ground floor, crossing from garage to building (big box in front of door 4 and 7)
func void tv_50(string ai_name)
{
ai2_spawn l_s99
ai2_spawn l_s98
music_stop
}

### GARAGE - 1ST FLOOR ###

#tv10 - left ramp between 1st floor and 2nd floor
func void spawnG3_12(string ai_name)
{
if (var_counter eq 0)
        {
        ai2_spawn garage_striker_09
        ai2_spawn garage_striker_10
        }
if (var_counter ne 0)
        {
        ai2_spawn garage_striker_09
        }
}

#tv15 - left ramp between 1st floor and 2nd floor, after tv10
func void killG3_12(string ai_name)
{
trigvolume_enable trigger_volume_G3_12 0 
}

#tv8 - right ramp between 1st floor and 2nd floor
func void spawnG3_8(string ai_name)
{
if (var_counter eq 0)
        {
        ai2_spawn garage_striker_03
        ai2_makeignoreplayer garage_striker_03 1
        ai2_spawn garage_striker_04
        ai2_spawn garage_striker_05
        ai2_lookatme garage_striker_04
        ai2_lookatme garage_striker_05
        playback_block garage_striker_03 garage_jump
        ai2_makeignoreplayer garage_striker_03 0
        }
if (var_counter ne 0)
        {
        ai2_spawn garage_striker_03
        ai2_makeignoreplayer garage_striker_03 1
        playback_block garage_striker_03 garage_jump
        ai2_makeignoreplayer garage_striker_03 0
        }
}

#tv14 - right ramp between 1st floor and 2nd floor, after tv8
func void killG3_11(string ai_name)
{
trigvolume_enable trigger_volume_G3_11 0 
}

#tv21 - 1st floor, crossing from garage to building (big box in front of door 5 and 8)
func void g_23(string ai_name)
{
ai2_spawn L2s_01
ai2_spawn L2s_02
ai2_spawn L2s_03
ai2_spawn L2tctf_01
ai2_spawn L2tctf_02
music_stop
trigvolume_enable trigger_volume_w_39 0
}

##tv31 - 1st floor, crossing from garage to building (box in front of door 2)
func void p_31(string ai_name)
{
trigvolume_enable trigger_volume_L2_4 1
}

### GARAGE - 2ND FLOOR ###

#tv11 - 2nd floor, crossing from garage to building (big box in front of door 6 and 9)
func void c_13(string ai_name)
{
ai2_spawn lobby_striker_20
ai2_spawn lobby_striker_21
ai2_spawn lobby_fodder01
ai2_spawn lobby_striker_05
trigvolume_enable vv_38t 0
trigvolume_enable a_18t 0
music_stop
}

### ENTRANCE HALL - GROUND FLOOR ###

#tv6 - in front of door 10
func void spawnL1_6(string ai_name)
{
ai2_spawn lobby_striker_06
trigvolume_enable tv_50t 0
}

#tv38 - after the passageway to the entrance hall with the van
func void x_05(string ai_name)
{
ai2_spawn l_c01
ai2_lookatme l_c01
ai2_passive l_c01 1
playback l_c01 lobby_runout
ai2_passive l_c01 0
trigvolume_enable trigger_volume_L1_6_9 0
}

#tv39 - in the passageway from the entrance hall with the van (near door 19)
func void y_32(string ai_name)
{
ai2_spawn l_t01
playback l_t01 lobby_backroll
sleep 15
ai2_spawn l_s02
ai2_spawn l_s03
trigvolume_enable tv_47t 0
}

#tv46 - after door 29
func void tv_46(string ai_name)
{
ai2_spawn l_s24
ai2_spawn l_t23
trigvolume_enable tv_47t 1
ai2_dopath l_t01 l_t01_06
ai2_setjobstate l_t01
}

#tv47 - in some distance after door 22
func void tv_47(string ai_name)
{
ai2_spawn l_s27
}

#tv66 - near door 26 and 31
func void room1_stop(string ai_name)
{
particle room1 do stop
}

#tv67 - near door 26 and 31, after tv66
func void room1_start(string ai_name)
{
particle room1 do start
particle smoke do start
}

#tv45 - after door 31
func void tv_45(string ai_name)
{
ai2_spawn a_v1
ai2_spawn l_s22
ai2_spawn l_s23
ai2_dopath l_t01 l_t01_03
ai2_setjobstate l_t01
ai2_dopath l_t23 l_t23_05
ai2_setjobstate l_t23
}

#tv44 - after door 26
func void tv_44(string ai_name)
{
ai2_spawn l_c10
ai2_dopath l_t01 l_t01_02
ai2_setjobstate l_t01
ai2_dopath l_t23 l_t23_03
ai2_setjobstate l_t23
}

#console1
func void goAttack(string ai_name)
{
music_stop
trigvolume_enable tv_57t 1
chr_delete l_c01
chr_delete l_s98
chr_delete l_s99
chr_delete lobby_striker_01
chr_delete lobby_striker_02
chr_delete garage_striker_01
chr_delete garage_striker_02
chr_delete garage_striker_03
chr_delete garage_striker_04
chr_delete garage_striker_05
chr_delete garage_striker_06
chr_delete garage_striker_07
chr_delete garage_striker_08
chr_delete garage_striker_09
chr_delete garage_striker_10
ai2_spawn tanker_stairdoor
particle stair_lock_locklight01 do start
objective_set 2 silent
target_set 1111 30
sound_dialog_play c00_01_27shinatama
}

#tv57 - huge box after door 19, 20 and 24
func void tv57(string ai_name)
{
sound_music_start mus_pursuit 0
sound_music_volume mus_pursuit 0.75 3.0
target_set 59 30
sleep 180
sound_dialog_play c00_01_105shinatama
}

### Pathfinding ###

#lose func of l_s02 and l_s03
func void unlock_follow(void)
{
var_counter2 = var_counter2 + 1
if(var_counter2 eq 2)
        {
        trigvolume_enable z_40t 1
        trigvolume_enable zz_40t 1
        trigvolume_enable zzz_40t 1
        trigvolume_enable zzzz_40t 1
        trigvolume_enable tv_61t 1
        }
}

func void patrolscript2222(void)
{
ai2_lookatchar l_t01 char_0
ai2_lookatchar l_t23 char_0
}

#tv42 - in front of door 19
func void z04(string ai_name)
{
ai2_dopath l_t01 l_t01_06
ai2_setjobstate l_t01
ai2_dopath l_t23 l_t23_06
ai2_setjobstate l_t23
}

#tv41 - after door 22
func void z02(string ai_name)
{
ai2_dopath l_t01 l_t01_04
ai2_setjobstate l_t01
ai2_dopath l_t23 l_t23_02
ai2_setjobstate l_t23
}

#tv40 - near door 29
func void z03(string ai_name)
{
ai2_dopath l_t01 l_t01_05
ai2_setjobstate l_t01
ai2_dopath l_t23 l_t23_01
ai2_setjobstate l_t23
}

#tv43 - in front of door 26 and 31, after tv67
func void z01(string ai_name)
{
ai2_dopath l_t01 l_t01_01
ai2_setjobstate l_t01
ai2_dopath l_t23 l_t23_04
ai2_setjobstate l_t23
}

#tv101 - staircase, between ground floor and 1st floor
func void z05(string ai_name)
{
ai2_dopath l_t01 l_t01_07
ai2_setjobstate l_t01
ai2_dopath l_t23 l_t23_07
ai2_setjobstate l_t23
}

### ENTRANCE HALL - 1ST FLOOR ###

#tv37 - after door 20
func void w_39(string ai_name)
{
ai2_spawn s2_t01
ai2_spawn s2_t02
ai2_spawn s2_s01
ai2_spawn s2_s02
ai2_spawn s2_s03
ai2_spawn s2_s05
ai2_spawn s2_t05
trigvolume_enable g_23t 0
}

#tv34 - after the passageway to the footbridge (left side after door 20)
func void u_36(string ai_name)
{
ai2_spawn cat1_02
trigvolume_enable trigger_volume_L2_4 0
}

#tv5 - other side of the footbridge
func void spawnL2_4(string ai_name)
{
ai2_spawn lobby_striker_04
playback lobby_striker_04 lobbystriker_roll
trigvolume_enable u_36t 0
}

#tv30 - next to tv5, staircase between 1st floor and 2nd floor (func: p_31t); not used

#tv23 - in some distance after door 98
func void i_24(string ai_name)
{
trigvolume_enable j_25t 0
trigvolume_enable h_06t 0
}

#tv24 - after tv23
func void j_25(string ai_name)
{
ai2_spawn L2s_11
}

#tv22 - after tv24
func void h_06(string ai_name)
{
ai2_spawn L2s_10
ai2_spawn Ls_15
ai2_spawn Ltctf_55
ai2_dopath L2tctf_01 patrol_L2_13
ai2_dopath L2tctf_02 patrol_L2_13
}

#tv33 - in some distance near door 33
func void t_35(string ai_name)
{
trigvolume_enable s_34t 0
}

#tv32 - after tv 33
func void s_34(string ai_name)
{
ai2_spawn Lcom_01
}

#tv27 - after door 33
func void m_28(string ai_name)
{
ai2_spawn Lv_40
ai2_spawn Lv_41
ai2_spawn Lc_43
ai2_spawn Ls_44
trigvolume_enable s_34t 1
}

#called up, after you've talked to the female cop
func void femcop_holster(string ai_name)
{
chr_forceholster Lc_43 1
}

#tv29 - after door 37
func void o_30(string ai_name)
{
ai2_spawn Ls_60
ai2_spawn a_v2
}

#tv28 - after door 32
func void n_29(string ai_name)
{
ai2_spawn Lc_50
ai2_spawn Ls_51
ai2_spawn Ls_12
}

### Pathfinding ###

#tv61 - big box in front of door 98
func void z06(string ai_name)
{
ai2_dopath l_t01 l_t01_08
ai2_setjobstate l_t01
ai2_dopath l_t23 l_t23_08
ai2_setjobstate l_t23
}

### ENTRANCE HALL - 2ND FLOOR ###

#tv20 - in front of door 24
func void f_22(string ai_name)
{
ai2_spawn lobby_striker_05
trigvolume_enable vv_38t 0
ai2_spawn lobby_striker_20
ai2_spawn lobby_fodder01
ai2_spawn lobby_striker_21
}

#tv18 - after door 24
func void d_20(string ai_name)
{
ai2_spawn l2_s46
ai2_spawn l2_s44
playback_block l2_s44 lobby_roll3
}

#tv35 - after the passageway to the footbridge (left side after door 24)
func void v_37(string ai_name)
{
ai2_spawn cat1_01
trigvolume_enable vv_38t 0
}

#tv36 - other side of the footbridge
func void vv_38(string ai_name)
{
ai2_spawn lobby_striker_05
ai2_spawn lobby_striker_20
ai2_spawn lobby_striker_21
ai2_spawn lobby_fodder01
trigvolume_enable v_37t 0
}

#tv19 - entrance to the room on the right side near door 24
func void e_21(string ai_name)
{
ai2_spawn lobby_striker_34
ai2_spawn lobby_victim05
ai2_spawn lobby_victim06
trigvolume_enable l_27t 0
}

#tv25 - in the room, around the place where the female civ gives you the w6_vdg
func void k_26(string ai_name)
{
trigvolume_enable l_27t 1
}

#tv26 - at the same place as tv19 (entrance to the room)
func void l_27(string ai_name)
{
ai2_spawn L3s_40
ai2_spawn L3s_41
}

#tv68 - in front of door 99
func void a_18(string ai_name)
{
trigvolume_enable b_19t 0
trigvolume_enable c_13t 0
}

#tv17 - after door 99, after tv68
func void b_19(string ai_name)
{
ai2_spawn lobby_striker_30
ai2_spawn lobby_striker_31
playback lobby_striker_31 lobby_roll2
trigvolume_enable d_20t 0
}

#tv69 - near door 40, in front of tv16
func void room2_stop(string ai_name)
{
particle room2 stop
}

#tv16 - near door 40, after tv69
func void room2_start(string ai_name)
{
particle room2 start
}

#tv49 - after door 40
func void tv_49(string ai_name)
{
ai2_spawn l2_s47
}

#tv71 - near door 38, in front of tv70
func void room3_stop(string ai_name)
{
particle room3 stop
}

#tv70 - near door 38, after tv71
func void room3_start(string ai_name)
{
particle room3 start
}

#tv48 - after door 38
func void tv_48(string ai_name)
{
ai2_spawn l2_s46
}

#console2
func void floor4_lock(void)
{
music_stop
particle floor4_lock_locklight01 do start
target_set 60 30
sound_dialog_play c00_01_28shinatama
}

### ENTRANCE HALL - 3RD FLOOR ###

#tv51 - after door 28
func void tv_51(string ai_name)
{
ai2_spawn l4_red1
ai2_spawn l4_t1
ai2_spawn l4_s1
ai2_spawn l4_s67
ai2_spawn l4_t2
ai2_spawn l4_s2
ai2_spawn l4_s3
ai2_spawn l4_f1
ai2_spawn l4_f2
ai2_spawn l4_f3
ai2_spawn l4_c66
ai2_kill l4_f1
ai2_kill l4_f2
ai2_kill l4_f3
ai2_kill l4_c66
}

#tv79 - after door 41
func void music_kidnap(void)
{
sleep 1
sound_music_start mus_om01 0.0
sound_music_volume mus_om01 0.75 3.0
#this music stopped in ta2_54 script
}

##########
### SP2 ###
##########

### GROUND FLOOR ###

#tv58 - after the end of the stairs
func void tv_58(string ai_name)
{
if(save_point eq 2) music_kidnap
else save_game 2 autosave
fork remove_ai
trigvolume_enable tv_58t 0
trigvolume_enable trigger_volume_80 0
door_lock 41
particle security_locklight01 do stop
objective_set 3 silent
target_set 60 30
var_counter = 0
}

#tv52 - in front of door 42
func void tv_52(string ai_name)
{
particle smoke do stop
ai2_spawn a_t03
ai2_passive a_t03 1
playback a_t03 atrium_run
sleep 7
ai2_spawn a_t06
sleep 7
ai2_spawn a_s02
sleep 7
ai2_spawn a_s03
sleep 7
ai2_spawn a_red1
ai2_passive a_t03 0
chr_set_health a_t05 900
chr_set_health a_t06 900
chr_set_health a_s02 900
chr_set_health a_s03 900
}

#tv72 - at the beginning of the stairs to the 2nd floor
func void room4_start(string ai_name)
{
particle room4 start
}

### 2ND FLOOR ###

#tv53 - at the end of the stairs to the 2nd floor
func void ta_53(string ai_name)
{
ai2_spawn a_t05
ai2_dopath a_s03 patrol_7043
ai2_setjobstate a_s03
ai2_dopath a_s02 patrol_7030
ai2_setjobstate a_s02
ai2_dopath a_t06 patrol_7034
ai2_setjobstate a_t06
ai2_dopath a_t05 patrol_7042
ai2_setjobstate a_t05
chr_set_health a_t05 40
chr_set_health a_t06 30
chr_set_health a_s02 80
chr_set_health a_s03 80
}

### 1ST FLOOR ###

#tv56 - at the end of the gangway from the 2nd floor to the 1st floor 
func void ta_53b(string ai_name)
{
chr_set_health a_t05 80
chr_set_health a_t06 60
chr_set_health a_s02 70
chr_set_health a_s03 80
}

#tv75 - after the end of the gangway from the 2nd floor to the 1st floor
func void room6_start(string ai_name)
{
particle room6 do start
}

#tv83 - after the middle of the floor, in front of tv73
func void room4_stop(string ai_name)
{
particle room4 do stop
}

#tv73 - after tv83 (func: room3_stop, already used above)

### 3RD FLOOR ###

#tv59 - after the end of the gangway from the 2nd floor to the 3rd floor
func void room5_stop(string ai_name)
{
particle room5 stop
}

#tv81 - in front of tv74
func void room5_start(string ai_name)
{
particle room5 start
}

#tv74 - in front of tv
func void room6_stop(string ai_name)
{
particle room6 stop
}

#tv82 - in front of the beginning of the gangway from the 3rd floor to the 4th floor (func: room4_stop, already used above)

### 4TH FLOOR ###

#tv98 - after the end of the gangway from the 3rd floor to the 4th floor
func void new_atrium(string ai_name)
{
ai2_spawn a_s07
ai2_spawn a_s05
ai2_spawn a_v3
}

#tv77 - complete room, which contains the console8 (func: check_death); I've disabled it

### 5TH FLOOR ###

#tv54 - after the end of the gangway from the 4th floor to the 5th floor
func void ta2_54(string ai_name)
{
ai2_spawn a2_t1
ai2_spawn a2_red1
ai2_spawn LSI
ai2_kill LSI
sleep 240
corpse_reset
music_stop
}

#tv103 - the complete room, where you get the laser torch
func void t103(string ai_name)
{
trigvolume_enable trigger_volume_103 0
if (chr_has_lsi(0))
        {
        trigvolume_enable trigger_volume_81 1
        objective_set 4 silent
        particle obj1 create
        target_set 9999 30
         }
else
        {
        sleep 60
        trigvolume_enable trigger_volume_103 1
        }
}

#tv80 - small flat box on the roof of the elevator
func void ta_62(string ai_name)
{
trigvolume_enable trigger_volume_81 0
particle obj1 kill
ai2_kill
fade_out 0 0 0 30
sleep 30
playback 0 ElevatorEndSet
fade_in 30
}

##########
### SP3 ###
##########

### GROUND FLOOR ###

#tv55 - after the elevator shaft
func void tsh_55(string ai_name)
{
if(save_point ne 3) save_game 3 autosave
trigvolume_enable tsh_55t 0
ai2_spawn sh_tank1
ai2_spawn sh_red1
ai2_spawn sh_s3
ai2_spawn sh_s4
ai2_spawn sh_s4b
objective_set 5 silent
target_set 58 30
env_show 501 0
env_show 502 0
env_show 503 0
env_show 504 0
env_show 601 1
env_show 602 1
sleep 120
ai2_attack sh_s3 char_0
}

#tv85 - at the same place as tv55 (func: s3; I've moved the save_game command to tv55, so this tv isn't any longer in use)

#console3
func void shin_lock(void)
{
particle shin_lock_locklight01 do start
particle roof_locklight01 do start
}

#tv104 - on the balustrade, near door 14
func void t102(string ai_name)
{
ai2_spawn mbo_sniper
ai2_spawn mbo_target
}

#tv76 - staircase, platform between ground floor and 1st floor
func void t62(string ai_name)
{
ai2_spawn sh_s1
ai2_spawn sh_s2
ai2_spawn sh_s6
}

### 1ST FLOOR ###

#tv78 - staircase, platform between 1st floor and 2nd floor
func void t72(string ai_name)
{
ai2_spawn sh_com1
ai2_spawn sh_tank2
ai2_spawn sh_s9
}

### 2ND FLOOR ###

#tv101 - after door 56
func void t98(string ai_name)
{
ai2_spawn a_v4
}

#tv60 - staircase, platform between 2nd floor and roof, in front of tv100
func void tsh_60(string ai_name)
{
ai2_spawn sh_s12
ai2_spawn sh_s12b
helicopter
}

func void helicopter(void)
{
obj_create 901 906
particle EndDust create
}

#tv100 - after tv60
func void t100(string ai_name)
{
ai2_spawn roof_tctf1
ai2_spawn sh_s12c
}

##########
### SP4 ###
##########

#tv63, if you leave the building on the right side
func void tr_65(string ai_name)
{
tr_67
}

#tv62, if you leave the building on the left side
func void tr_64(string ai_name)
{
tr_67
}

#tv64 - after the window, which is behind the tctf cop
func void tr_66(string ai_name)
{
tr_67
}

#tv65 - after the other window on this side
func void tr_67(string ai_name)
{
trigvolume_enable tsh_60t 0
trigvolume_enable tr_64t 0
trigvolume_enable tr_65t 0
trigvolume_enable tr_66t 0
trigvolume_enable tr_67t 0
if(save_point eq 4) helicopter
else save_game 4 autosave
objective_set 5 silent
target_set 1 0
sleep 1
sound_ambient_start c08_heli 1.0
fork helicopter_sound_stop
chr_create 1019 start
chr_create 1020 start
chr_create 1021 start
chr_changeteam 1019 Syndicate
chr_changeteam 1020 Syndicate
chr_changeteam 1021 Syndicate
chr_envanim 1019 HeliOutroShinBox01
chr_envanim 1020 HeliOutroStrBox01
chr_envanim 1021 HeliOutroStrBox02
chr_animate 1019 SHINATstand_heli 1000
chr_animate 1020 STRIKEstand_heli 1000
chr_animate 1021 STRIKEcrouch_idle 1000
env_anim 901 906
particle EndDust kill
ai2_spawn barabus
chr_boss_shield barabus
ai2_lookatchar barabus 0
sound_music_start mus_asianb 0
sound_music_volume mus_asianb 2
sleep 600
chr_delete 1019
chr_delete 1020
chr_delete 1021
sleep 600
obj_kill 901 906
sound_ambient_stop c08_heli
}

func void helicopter_sound_stop(void)
{
sleep 680
sound_ambient_volume c08_heli 0.0 12
}

#tv1 and tv84 - the side after the window, which is behind the tctf cop
func void BarabasSouth(string barabas)
{
sound_ambient_start c11_10_14bar_jet
playback barabus BarabasSouth
ai2_barabbas_retrievegun barabus
sleep 60
chr_envanim barabus BarabasSouthBox norotation
chr_animate barabus BARABsouth
}

#tv4 - the next side, if you go anticlockwise
func void BarabasEast(string barabas)
{
sound_ambient_start c11_10_14bar_jet
playback barabus BarabasEast
ai2_barabbas_retrievegun barabus
sleep 60
chr_envanim barabus BarabasEastBox norotation
chr_animate barabus BARABeast
}

#tv2 - the next side, if you go anticlockwise
func void BarabasNorth(string barabas)
{
sound_ambient_start c11_10_14bar_jet
playback barabus BarabasNorth
ai2_barabbas_retrievegun barabus
sleep 60
chr_envanim barabus BarabasNorthBox norotation
chr_animate barabus BARABnorth
}

#tv3 - the next side, if you go anticlockwise
func void BarabasWest(string barabas)
{
sound_ambient_start c11_10_14bar_jet
playback barabus BarabasWest
ai2_barabbas_retrievegun barabus
sleep 60
chr_envanim barabus BarabasWestBox norotation
chr_animate barabus BARABwest
}

#lose func of barabus
func void final(void)
{
fade_out 0 0 0 30
sleep 30
win
}

#####################
### TEXT CONSOLES ###
#####################

func void level_8a(void)
{
text_console level_8a
console_reset 17
}

func void level_8b(void)
{
text_console level_8b
console_reset 12
}

func void level_8c(void)
{
text_console level_8c
console_reset 14
}

func void level_8d(void)
{
text_console level_8d
console_reset 16
}

func void level_8e(void)
{
text_console level_8e
console_reset 15
}

func void level_8f(void)
{
text_console level_8f
console_reset 13
}