source: oup/current/Tool_TxmpReplace.pas @ 43

unit Tool_TxmpReplace;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls, StrUtils, Code_Functions, Data, Code_OniImgClass;

type
  TForm_TxmpReplace = class(TForm)
    panel_12: TPanel;
    group_txmpselect: TGroupBox;
    splitter_txmp: TSplitter;
    list_txmp: TListBox;
    Splitter1: TSplitter;
    group_bmpselect: TGroupBox;
    panel_load: TPanel;
    btn_load: TButton;
    image_bmppreview: TImage;
    opend:    TOpenDialog;
    group_options: TGroupBox;
    btn_replace: TButton;
    check_transparency: TCheckBox;
    check_fading: TCheckBox;
    panel_txmppreview: TPanel;
    btn_save: TButton;
    image_txmppreview: TImage;
    saved:    TSaveDialog;
    procedure FormCreate(Sender: TObject);
    procedure btn_saveClick(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure btn_replaceClick(Sender: TObject);
    procedure btn_loadClick(Sender: TObject);
    procedure list_txmpClick(Sender: TObject);
    procedure Recreatelist;
    procedure list_txmpMouseDown(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
  private
    OniImage_Old: TOniImage;
    OniImage_New: TOniImage;
  public
  end;

var
  Form_TxmpReplace: TForm_TxmpReplace;

implementation

uses Main, Code_OniDataClass;

{$R *.dfm}



procedure TForm_TxmpReplace.Recreatelist;
var
  files: TStringArray;
  i:     LongWord;
begin
  list_txmp.Items.Clear;
  files := OniDataConnection.GetFilesList('TXMP', '', True);
  if Length(files) > 0 then
    for i := 0 to High(files) do
      list_txmp.Items.Add(files[i]);
  group_bmpselect.Enabled := False;
  check_transparency.Checked := False;
  check_fading.Checked := False;
end;




procedure TForm_TxmpReplace.list_txmpClick(Sender: TObject);
var
  id:   LongWord;
  Data: Tdata;
  mem:  TMemoryStream;
  fadingbyte, depthbyte, storebyte: Byte;
begin
  id := OniDataConnection.ExtractFileID(list_txmp.Items.Strings[list_txmp.ItemIndex]);
  OniDataConnection.LoadDatFilePart(id, $88, SizeOf(fadingbyte), @fadingbyte);
  OniDataConnection.LoadDatFilePart(id, $89, SizeOf(depthbyte), @depthbyte);
  OniDataConnection.LoadDatFilePart(id, $90, SizeOf(storebyte), @storebyte);
  check_fading.Checked := (fadingbyte and $01) > 0;
  check_transparency.Checked := (depthbyte and $04) > 0;

  OniImage_Old.LoadFromTXMP(id);
  Data := OniImage_Old.GetAsBMP;
  mem  := TMemoryStream.Create;
  mem.Write(Data[0], Length(Data));
  mem.Seek(0, soFromBeginning);
  image_txmppreview.Picture.Bitmap.LoadFromStream(mem);
  mem.Free;

  group_bmpselect.Enabled := True;
end;




procedure TForm_TxmpReplace.list_txmpMouseDown(Sender: TObject;
  Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
var
  pt: TPoint;
begin
  pt.X := x;
  pt.Y := y;
  list_txmp.ItemIndex := list_txmp.ItemAtPos(pt, true);
  if list_txmp.ItemIndex > -1 then
    Self.list_txmpClick(Self);
end;

procedure TForm_TxmpReplace.btn_loadClick(Sender: TObject);
var
  mem:   TMemoryStream;
  tempd: Tdata;
begin
  if opend.Execute then
  begin
    OniImage_New.LoadFromBMP(opend.FileName);
    tempd := OniImage_New.GetAsBMP;
    mem   := TMemoryStream.Create;
    mem.Write(tempd[0], Length(tempd));
    mem.Seek(0, soFromBeginning);
    image_bmppreview.Picture.Bitmap.LoadFromStream(mem);
    mem.Free;
    group_options.Enabled := True;
  end;
end;




procedure TForm_TxmpReplace.btn_replaceClick(Sender: TObject);
var
  id: LongWord;

  oldsize, newsize: LongWord;
  old_rawaddr, new_rawaddr: LongWord;
  oldfading: Byte;
  tempd:     Tdata;

  datbyte: Word;
begin
  if list_txmp.ItemIndex >= 0 then
  begin
    id := OniDataConnection.ExtractFileID(list_txmp.Items.Strings[list_txmp.ItemIndex]);
    OniDataConnection.LoadDatFilePart(id, $88, 1, @oldfading);
    if OniDataConnection.OSisMac then
      OniDataConnection.UpdateDatFilePart(id, $A0, 4, @old_rawaddr)
    else
      OniDataConnection.LoadDatFilePart(id, $9C, 4, @old_rawaddr);

    if (OniImage_Old.Width <> OniImage_New.Width) or
      (OniImage_Old.Height <> OniImage_New.Height) then
    begin
      if MessageBox(Self.Handle, PChar(
        'Current image and new image have different size' + CrLf +
        '(Current: ' + IntToStr(OniImage_Old.Width) +
        'x' + IntToStr(OniImage_Old.Height) + ' - New: ' +
        IntToStr(OniImage_New.Width) + 'x' + IntToStr(OniImage_New.Height) + ')' + CrLf +
        'Replace anyways?'),
        PChar(list_txmp.Items.Strings[list_txmp.ItemIndex]),
        MB_YESNO) = idNo then
        Exit;
    end;

    oldsize := OniImage_Old.GetImageDataSize((oldfading and $01) > 0);

    if check_fading.Checked then
      if not OniImage_New.GetMipMappedImage(tempd) then
        if MessageBox(Self.Handle,
          PChar('Can not create a MipMapped-image (probably because of a wrong dimension).' +
          #13 + #10 + 'Do you want to continue without MipMapping?'), PChar('Warning'),
          MB_YESNO) = ID_YES then
          check_fading.Checked := False
        else
          Exit;

    if not check_fading.Checked then
      tempd := OniImage_New.GetAsData;

    newsize := OniImage_New.GetImageDataSize(check_fading.Checked);
    ShowMessage(IntToStr(newsize));

    if (newsize > oldsize) and (OniDataConnection.Backend = ODB_Dat) then
      new_rawaddr := OniDataConnection.AppendRawFile(
        OniDataConnection.OSisMac, Length(tempd), tempd)
    else
    begin
      new_rawaddr := old_rawaddr;
      OniDataConnection.UpdateRawFile(id, $9C, Length(tempd), tempd);
    end;

    datbyte := $00;
    if check_fading.Checked then
      datbyte := datbyte or $01;
    OniDataConnection.UpdateDatFilePart(id, $88, 1, @datbyte);
    datbyte := $10;
    if check_transparency.Checked then
      datbyte := datbyte or $04;
    OniDataConnection.UpdateDatFilePart(id, $89, 1, @datbyte);
    OniDataConnection.UpdateDatFilePart(id, $8C, 2, @OniImage_New.Width);
    OniDataConnection.UpdateDatFilePart(id, $8E, 2, @OniImage_New.Height);
    datbyte := $08;
    OniDataConnection.UpdateDatFilePart(id, $90, 1, @datbyte);
    if OniDataConnection.OSisMac then
      OniDataConnection.UpdateDatFilePart(id, $A0, 4, @new_rawaddr)
    else
      OniDataConnection.UpdateDatFilePart(id, $9C, 4, @new_rawaddr);

    ShowMessage('TXMP-image replaced');
  end;
end;




procedure TForm_TxmpReplace.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  OniImage_Old.Free;
  OniImage_New.Free;
  Action := caFree;
end;




procedure TForm_TxmpReplace.FormCreate(Sender: TObject);
begin
  OniImage_Old := TOniImage.Create;
  OniImage_New := TOniImage.Create;
end;




procedure TForm_TxmpReplace.btn_saveClick(Sender: TObject);
begin
  if saved.Execute then
    OniImage_Old.WriteToBMP(saved.FileName);
end;

end.